Coincidir con espacios en blanco pero no con nuevas líneas

Resumen

• Úselo \hpara hacer coincidir espacios en blanco horizontales, en Perl desde v5.10.0 (lanzado en 2007)
• Para motores que no sean PCRE , utilice un doble negativo:[^\S\r\n]
• Propiedades Unicode: \p{Blank}o\p{HorizSpace}
• Sea directo, en ASCII:[\t\f\cK ]
• Sea directo, en Unicode (pero no lo haga, en realidad)
• Otras aplicaciones de dobles negativos y propiedades Unicode

Espacios en blanco horizontales

La sección "Clases de personajes y otros escapes especiales" de perlre incluye

• \hespacios en blanco horizontales
• \HNo espacios en blanco horizontales

Doble negativa

Si puede utilizar su patrón con otros motores, particularmente aquellos que no son compatibles con Perl o que no admiten \h, expréselo como un doble negativo:

[^\S\r\n]

Es decir, no-no-espacios en blanco (los Scomplementos mayúsculas) o no-retorno-de-carro o no-nueva línea. Distribuir el not externo ( es decir , el complemento ^en la clase de caracteres entre corchetes ) con la ley de De Morgan , esto equivale a restar \ry \nde \s. La inclusión de retorno de carro y nueva línea en el patrón maneja correctamente todas las convenciones de nueva línea de Unix (LF), Mac OS clásico (CR) y DOS-ish (CRLF) .

No es necesario que confíes en mi palabra:

#! /usr/bin/env perl

use strict;
use warnings;

my $ws_not_crlf = qr/[^\S\r\n]/;

for (' ', '\f', '\t', '\r', '\n') {
  my $qq = qq["$_"];
  printf "%-4s => %s\n", $qq,
    (eval $qq) =~ $ws_not_crlf ? "match" : "no match";
}

Producción:

" " => coincidencia
"\f" => coincidencia
"\t" => coincidencia
"\r" => no coincide
"\n" => no coincide

Tenga en cuenta la exclusión de la pestaña vertical, pero esto se aborda en v5.18 .

Antes de objetar demasiado duramente, la documentación de Perl utiliza la misma técnica. Una nota a pie de página en la sección "Espacio en blanco" de perlrecharclass dice

Antes de Perl v5.18, \sno coincidía con la pestaña vertical. [^\S\cK](oscuramente) coincide con lo que \stradicionalmente se hacía.

Propiedades Unicode

La documentación de Perlre antes mencionada \hhace\H referencia a la documentación de Perlunicode donde leemos sobre una familia de propiedades Unicode útiles.

• \p{Blank}
  • Esto es lo mismo que \hy \p{HorizSpace}: un carácter que cambia el espaciado horizontalmente.
• \p{HorizSpace}
  • Esto es lo mismo que \hy \p{Blank}: un carácter que cambia el espaciado horizontalmente.

El enfoque directo: edición ASCII

La sección "Espacio en blanco" de perlrecharclass también sugiere otros enfoques que no ofenderán la oposición de los profesores de gramática a los dobles negativos.

Di lo que quieres en lugar de lo que no quieres.

Fuera de las reglas locales y Unicode o cuando el modificador /ao/aa está en vigor, " \scoincide con [\t\n\f\r ]y, a partir de Perl v5.18, la pestaña vertical \cK".

Para hacer coincidir los espacios en blanco pero no las nuevas líneas (en sentido amplio), descarte \ry \nsalga

[\t\f\cK ]

El enfoque directo: edición Unicode

Si su texto es Unicode, use un código similar al siguiente para construir un patrón a partir de la tabla en la sección "Espacio en blanco" de perlrecharclass .

sub ws_not_nl {
  local($_) = <<'EOTable';
0x0009        CHARACTER TABULATION   h s
0x000a              LINE FEED (LF)    vs
0x000b             LINE TABULATION    vs  [1]
0x000c              FORM FEED (FF)    vs
0x000d        CARRIAGE RETURN (CR)    vs
0x0020                       SPACE   h s
0x0085             NEXT LINE (NEL)    vs  [2]
0x00a0              NO-BREAK SPACE   h s  [2]
0x1680            OGHAM SPACE MARK   h s
0x2000                     EN QUAD   h s
0x2001                     EM QUAD   h s
0x2002                    EN SPACE   h s
0x2003                    EM SPACE   h s
0x2004          THREE-PER-EM SPACE   h s
0x2005           FOUR-PER-EM SPACE   h s
0x2006            SIX-PER-EM SPACE   h s
0x2007                FIGURE SPACE   h s
0x2008           PUNCTUATION SPACE   h s
0x2009                  THIN SPACE   h s
0x200a                  HAIR SPACE   h s
0x2028              LINE SEPARATOR    vs
0x2029         PARAGRAPH SEPARATOR    vs
0x202f       NARROW NO-BREAK SPACE   h s
0x205f   MEDIUM MATHEMATICAL SPACE   h s
0x3000           IDEOGRAPHIC SPACE   h s
EOTable

  my $class;
  while (/^0x([0-9a-f]{4})\s+([A-Z\s]+)/mg) {
    my($hex,$name) = ($1,$2);
    next if $name =~ /\b(?:CR|NL|NEL|SEPARATOR)\b/;
    $class .= "\\N{U+$hex}";
  }

  qr/[$class]/u;
}

Lo anterior es para completar. Utilice las propiedades Unicode en lugar de escribirlas a mano.

Otras aplicaciones

El truco del doble negativo también es útil para hacer coincidir caracteres alfabéticos. Recuerde que \wcoincide con "caracteres de palabras", caracteres alfabéticos y dígitos y guión bajo. Nosotros, los feos estadounidenses, a veces queremos escribirlo como, digamos,

if (/[A-Za-z]+/) { ... }

pero una clase de carácter doble negativo puede respetar la configuración regional:

if (/[^\W\d_]+/) { ... }

Expresar “un carácter de palabra pero no un dígito ni un guión bajo” de esta manera es un poco opaco. Una clase de caracteres POSIX comunica la intención de forma más directa

if (/[[:alpha:]]+/) { ... }

o con una propiedad Unicode como sugirió szbalint

if (/\p{Letter}+/) { ... }

Pingui preguntó acerca de anidar la clase de carácter doble negativo para modificar efectivamente \sel

/(\+|0|\()[\d()\s-]{6,20}\d/g

Lo mejor que se me ocurrió es utilizar |una alternativa y moverla \sa la otra rama:

/(\+|0|\()(?:[\d()-]|[^\S\r\n]){6,20}\d/g

Aug 12 '2010 15:08 Greg Bacon