¿Cómo puedo ejecutar código en un hilo en segundo plano y aún así acceder a la interfaz de usuario?

Si bien me alegra que hayas encontrado una solución, te desaconsejo usarla Application.DoEvents()porque es una mala práctica .

Consulte esta publicación de blog: Cómo mantener la capacidad de respuesta de su interfaz de usuario y los peligros de Application.DoEvents .

En pocas palabras, Application.DoEvents()es una solución sucia que hace que su interfaz de usuario parezca receptiva porque obliga al hilo de la interfaz de usuario a manejar todos los mensajes de ventana disponibles actualmente. WM_PAINTes uno de esos mensajes por lo que su ventana se vuelve a dibujar.

Sin embargo, esto tiene algunos inconvenientes... Por ejemplo:

• Si cerrara el formulario durante este proceso "en segundo plano", lo más probable es que arrojara un error.

• Otro inconveniente es que si el ScanButtonInForm1()método se llama haciendo clic en un botón, podrá volver a hacer clic en ese botón (a menos que configure Enabled = False) y comenzar el proceso una vez más, lo que nos lleva a otro inconveniente:

• Cuantos más Application.DoEvents()bucles inicie, más ocupará el subproceso de la interfaz de usuario, lo que hará que el uso de la CPU aumente con bastante rapidez. Dado que cada bucle se ejecuta en el mismo subproceso, su procesador no puede programar el trabajo en diferentes núcleos ni subprocesos, por lo que su código siempre se ejecutará en un núcleo, consumiendo la mayor cantidad de CPU posible.

El reemplazo es, por supuesto, un subproceso múltiple adecuado (o la Biblioteca paralela de tareas , lo que prefiera). En realidad, el multiproceso regular no es tan difícil de implementar.

Los basicos

Para crear un nuevo hilo solo necesitas declarar una instancia de la Threadclase y pasar un delegado al método que deseas que ejecute el hilo:

Dim myThread As New Thread(AddressOf <your method here>)

... entonces debes establecer su IsBackgroundpropiedad en Truesi quieres que se cierre automáticamente cuando se cierre el programa (de lo contrario, mantendrá el programa abierto hasta que finalice el hilo).

¡ Luego simplemente llamas Start()y tendrás un hilo en segundo plano en ejecución!

Dim myThread As New Thread(AddressOf myThreadMethod)
myThread.IsBackground = True
myThread.Start()

Accediendo al hilo de la interfaz de usuario

La parte complicada del subproceso múltiple es reunir las llamadas al subproceso de la interfaz de usuario. Un subproceso en segundo plano generalmente no puede acceder a elementos (controles) en el subproceso de la interfaz de usuario porque eso podría causar problemas de concurrencia (dos subprocesos acceden al mismo control al mismo tiempo). Por lo tanto, debe ordenar sus llamadas a la UI programándolas para su ejecución en el propio subproceso de la UI . De esa manera, ya no correrá el riesgo de concurrencia porque todo el código relacionado con la interfaz de usuario se ejecuta en el subproceso de la interfaz de usuario.

Para clasificar las llamadas al subproceso de la interfaz de usuario, utilice cualquiera de los métodos Control.Invoke()o Control.BeginInvoke(). BeginInvoke()es la versión asincrónica , lo que significa que no espera a que se complete la llamada de la interfaz de usuario antes de permitir que el subproceso en segundo plano continúe con su trabajo.

También debe asegurarse de verificar la Control.InvokeRequiredpropiedad , que le indica si ya está en el hilo de la interfaz de usuario (en cuyo caso invocarlo es extremadamente innecesario) o no.

El patrón básico InvokeRequired/Invokese ve así (principalmente como referencia, sigue leyendo a continuación para conocer formas más breves):

'This delegate will be used to tell Control.Invoke() which method we want to invoke on the UI thread.
Private Delegate Sub UpdateTextBoxDelegate(ByVal TargetTextBox As TextBox, ByVal Text As String)

Private Sub myThreadMethod() 'The method that our thread runs.
    'Do some background stuff...

    If Me.InvokeRequired = True Then '"Me" being the current form.
        Me.Invoke(New UpdateTextBoxDelegate(AddressOf UpdateTextBox), TextBox1, "Status update!") 'We are in a background thread, therefore we must invoke.
    Else
        UpdateTextBox(TextBox1, "Status update!") 'We are on the UI thread, no invoking required.
    End If

    'Do some more background stuff...
End Sub

'This is the method that Control.Invoke() will execute.
Private Sub UpdateTextBox(ByVal TargetTextBox As TextBox, ByVal Text As String)
    TargetTextBox.Text = Text
End Sub

New UpdateTextBoxDelegate(AddressOf UpdateTextBox)crea una nueva instancia de UpdateTextBoxDelegateque apunta a nuestro UpdateTextBoxmétodo (el método a invocar en la interfaz de usuario).

Sin embargo, a partir de Visual Basic 2010 (10.0) y superiores , puede usar expresiones Lambda , lo que facilita mucho la invocación :

Private Sub myThreadMethod()
    'Do some background stuff...

    If Me.InvokeRequired = True Then '"Me" being the current form.
        Me.Invoke(Sub() TextBox1.Text = "Status update!") 'We are in a background thread, therefore we must invoke.
    Else
        TextBox1.Text = "Status update!" 'We are on the UI thread, no invoking required.
    End If

    'Do some more background stuff...
End Sub

Ahora todo lo que tienes que hacer es escribir Sub()y luego continuar escribiendo código como si estuvieras en un método normal:

If Me.InvokeRequired = True Then
    Me.Invoke(Sub()
                  TextBox1.Text = "Status update!"
                  Me.Text = "Hello world!"
                  Label1.Location = New Point(128, 32)
                  ProgressBar1.Value += 1
              End Sub)
Else
    TextBox1.Text = "Status update!"
    Me.Text = "Hello world!"
    Label1.Location = New Point(128, 32)
    ProgressBar1.Value += 1
End If

¡Y así es como diriges las llamadas al hilo de la interfaz de usuario!

Haciéndolo más simple

Para que sea aún más sencillo invocar a la interfaz de usuario, puede crear un método de extensión que invoque y InvokeRequiredverifique por usted.

Coloque esto en un archivo de código separado:

Imports System.Runtime.CompilerServices

Public Module Extensions
    ''' <summary>
    ''' Invokes the specified method on the calling control's thread (if necessary, otherwise on the current thread).
    ''' </summary>
    ''' <param name="Control">The control which's thread to invoke the method at.</param>
    ''' <param name="Method">The method to invoke.</param>
    ''' <param name="Parameters">The parameters to pass to the method (optional).</param>
    ''' <remarks></remarks>
    <Extension()> _
    Public Function InvokeIfRequired(ByVal Control As Control, ByVal Method As [Delegate], ByVal ParamArray Parameters As Object()) As Object
        If Parameters IsNot Nothing AndAlso _
            Parameters.Length = 0 Then Parameters = Nothing

        If Control.InvokeRequired = True Then
            Return Control.Invoke(Method, Parameters)
        Else
            Return Method.DynamicInvoke(Parameters)
        End If
    End Function
End Module

Ahora solo necesita llamar a este método único cuando desee acceder a la interfaz de usuario, no If-Then-Elsese requiere nada adicional:

Private Sub myThreadMethod()
    'Do some background stuff...

    Me.InvokeIfRequired(Sub()
                            TextBox1.Text = "Status update!"
                            Me.Text = "Hello world!"
                            Label1.Location = New Point(128, 32)
                        End Sub)

    'Do some more background stuff...
End Sub

Devolver objetos/datos de la interfaz de usuario conInvokeIfRequired()

Con mi InvokeIfRequired()método de extensión también puedes devolver objetos o datos del hilo de la interfaz de usuario de una manera sencilla. Por ejemplo, si quieres el ancho de una etiqueta:

Dim LabelWidth As Integer = Me.InvokeIfRequired(Function() Label1.Width)

Ejemplo

El siguiente código incrementará un contador que le indicará cuánto tiempo se ha ejecutado el hilo:

Private Sub Button1_Click(sender As System.Object, e As System.EventArgs) Handles Button1.Click
    Dim CounterThread As New Thread(AddressOf CounterThreadMethod)
    CounterThread.IsBackground = True
    CounterThread.Start()

    Button1.Enabled = False 'Make the button unclickable (so that we cannot start yet another thread).
End Sub

Private Sub CounterThreadMethod()
    Dim Time As Integer = 0

    While True
        Thread.Sleep(1000) 'Wait for approximately 1000 ms (1 second).
        Time += 1

        Me.InvokeIfRequired(Sub() Label1.Text = "Thread has been running for: " & Time & " seconds.")
    End While
End Sub

¡Espero que esto ayude!

Aug 08 '2017 14:08 Visual Vincent