¿Por qué LINQ JOIN es mucho más rápido que vincular con WHERE?

Recientemente actualicé a VS 2010 y estoy jugando con LINQ to Dataset. Tengo un conjunto de datos de tipo seguro para Autorización que se encuentra en HttpCache de una aplicación web ASP.NET.

Entonces quería saber cuál es realmente la forma más rápida de verificar si un usuario está autorizado a hacer algo. Aquí está mi modelo de datos y alguna otra información si alguien está interesado.

He comprobado 3 formas:

base de datos directa
Consulta LINQ con condiciones Where como "Unirse" - Sintaxis
Consulta LINQ con Join - Sintaxis

Estos son los resultados con 1000 llamadas a cada función:

1.Iteración:

4,2841519 seg.
115,7796925 seg.
2,024749 seg.

2.Iteración:

3,1954857 seg.
84,97047 seg.
1,5783397 seg.

3.Iteración:

2,7922143 seg.
97,8713267 seg.
1,8432163 seg.

Promedio:

Base de datos: 3,4239506333 seg.
Dónde: 99,5404964 seg.
Unirse: 1,815435 seg.

¿Por qué la versión Join es mucho más rápida que la sintaxis dónde, lo que la hace inútil aunque, como novato en LINQ, parece ser la más legible? ¿O me he perdido algo en mis consultas?

Aquí están las consultas LINQ, me salto la base de datos:

Dónde :

Public Function hasAccessDS_Where(ByVal accessRule As String) As Boolean
    Dim userID As Guid = DirectCast(Membership.GetUser.ProviderUserKey, Guid)
    Dim query = From accRule In Authorization.dsAuth.aspnet_AccessRule, _
                roleAccRule In Authorization.dsAuth.aspnet_RoleAccessRule, _
                role In Authorization.dsAuth.aspnet_Roles, _
                userRole In Authorization.dsAuth.aspnet_UsersInRoles _
                Where accRule.idAccessRule = roleAccRule.fiAccessRule _
                And roleAccRule.fiRole = role.RoleId _
                And userRole.RoleId = role.RoleId _
                And userRole.UserId = userID And accRule.RuleName.Contains(accessRule)
                Select accRule.idAccessRule
    Return query.Any
End Function

Unirse:

Public Function hasAccessDS_Join(ByVal accessRule As String) As Boolean
    Dim userID As Guid = DirectCast(Membership.GetUser.ProviderUserKey, Guid)
    Dim query = From accRule In Authorization.dsAuth.aspnet_AccessRule _
                Join roleAccRule In Authorization.dsAuth.aspnet_RoleAccessRule _
                On accRule.idAccessRule Equals roleAccRule.fiAccessRule _
                Join role In Authorization.dsAuth.aspnet_Roles _
                On role.RoleId Equals roleAccRule.fiRole _
                Join userRole In Authorization.dsAuth.aspnet_UsersInRoles _
                On userRole.RoleId Equals role.RoleId _
                Where userRole.UserId = userID And accRule.RuleName.Contains(accessRule)
                Select accRule.idAccessRule
    Return query.Any
End Function

Gracias de antemano.

Editar : después de algunas mejoras en ambas consultas para obtener valores de rendimiento más significativos, la ventaja de JOIN es incluso muchas veces mayor que antes:

Unirse :

Public Overloads Shared Function hasAccessDS_Join(ByVal userID As Guid, ByVal idAccessRule As Int32) As Boolean
    Dim query = From accRule In Authorization.dsAuth.aspnet_AccessRule _
                   Join roleAccRule In Authorization.dsAuth.aspnet_RoleAccessRule _
                   On accRule.idAccessRule Equals roleAccRule.fiAccessRule _
                   Join role In Authorization.dsAuth.aspnet_Roles _
                   On role.RoleId Equals roleAccRule.fiRole _
                   Join userRole In Authorization.dsAuth.aspnet_UsersInRoles _
                   On userRole.RoleId Equals role.RoleId _
                   Where accRule.idAccessRule = idAccessRule And userRole.UserId = userID
             Select role.RoleId
    Return query.Any
End Function

Dónde :

Public Overloads Shared Function hasAccessDS_Where(ByVal userID As Guid, ByVal idAccessRule As Int32) As Boolean
    Dim query = From accRule In Authorization.dsAuth.aspnet_AccessRule, _
           roleAccRule In Authorization.dsAuth.aspnet_RoleAccessRule, _
           role In Authorization.dsAuth.aspnet_Roles, _
           userRole In Authorization.dsAuth.aspnet_UsersInRoles _
           Where accRule.idAccessRule = roleAccRule.fiAccessRule _
           And roleAccRule.fiRole = role.RoleId _
           And userRole.RoleId = role.RoleId _
           And accRule.idAccessRule = idAccessRule And userRole.UserId = userID
           Select role.RoleId
    Return query.Any
End Function

Resultado de 1000 llamadas (en una computadora más rápida)

Unirse | 2. donde

1.Iteración:

0,0713669 seg.
12,7395299 seg.

2.Iteración:

0,0492458 seg.
12,3885925 seg.

3.Iteración:

0,0501982 seg.
13,3474216 seg.

Promedio:

Unirse: 0,0569367 seg.
Donde: 12,8251813 seg.

Unirse es 225 veces más rápido

Conclusión: evite DÓNDE especificar relaciones y use JOIN siempre que sea posible (definitivamente en LINQ to DataSet y Linq-To-Objectsen general).

Apr 05 '11 18:04 Tim Schmelter

Su primer enfoque (consulta SQL en la base de datos) es bastante eficiente porque la base de datos sabe cómo realizar una unión. Pero realmente no tiene sentido compararlo con otros enfoques, ya que funcionan directamente en la memoria (Linq to DataSet).
La consulta con varias tablas y una Wherecondición en realidad realiza un producto cartesiano de todas las tablas y luego filtra las filas que satisfacen la condición. Esto significa que la Wherecondición se evalúa para cada combinación de filas (n1 * n2 * n3 * n4)
El Joinoperador toma las filas de las primeras tablas, luego toma solo las filas con una clave coincidente de la segunda tabla, luego solo las filas con una clave coincidente de la tercera tabla, y así sucesivamente. Esto es mucho más eficiente, porque no necesita realizar tantas operaciones.

Apr 05 '2011 12:04 Thomas Levesque

Es Joinmucho más rápido, porque el método sabe cómo combinar las tablas para reducir el resultado a las combinaciones relevantes. Cuando utiliza Wherepara especificar la relación, debe crear todas las combinaciones posibles y luego probar la condición para ver qué combinaciones son relevantes.

El Joinmétodo puede configurar una tabla hash para usarla como índice para comprimir rápidamente dos tablas juntas, mientras que el Wheremétodo se ejecuta después de que todas las combinaciones ya estén creadas, por lo que no puede usar ningún truco para reducir las combinaciones de antemano.

Apr 05 '2011 11:04 Guffa

Lo que realmente necesitas saber es el SQL que se creó para las dos declaraciones. Hay varias formas de acceder a él, pero la más sencilla es utilizar LinqPad. Hay varios botones justo encima de los resultados de la consulta que cambiarán al sql. Eso te dará mucha más información que cualquier otra cosa.

Sin embargo, gran información que compartiste allí.

Apr 05 '2011 11:04 phillip